3D models: the sphere

When working in 3D, there is always a need of 3D basic models to try new algorithms or to use them as building blocks. In this post, we'll see how to build a sphere and how we can move it in 3D without any additional plugins.

Creating a sphere

A sphere of center C (xc,yc,zc) and of radius R is easily built from the function Process > Math > Macro... by using the formula:

(x - x_c)² +(y - y_c)² +(z - z_c)² <= R²

Here is a small IJ script creating a 8-bit stack of 101x101x101 voxels containing a white sphere of radius 50.

radius=50;
newImage("sphere", "8-bit Black", radius*2+1, radius*2+1, radius*2+1);
code="code=[if (pow((x-50),2)+pow((y-50),2)+pow((z-50),2)<=50*50) v=255]";
options=" stack";
run("Macro...", code+options);

Translating spheres

Imagine that we want to display several spheres of variable radii and locations as shown in Fig. 1.

Fig.1: Random spheres visualized with Plugins > 3D > Volume Viewer

A naive implementation would use the Process > Math > Macro... function to display the spheres, but the Macro... scans the entire volume to display (or not) the voxels and if you work with a large volume, your script 'll be really slow.
It's better to create a single sphere which 'll be used as a template. Then, the only operations for translating a sphere into a large target volume consists of a copy (clone) and paste at the right location that can be done in 2D.
In the following script, the template is a 101x101x101 8-bit stack containing a sphere of radius 50 (lines 11-13) created by the function initSphere(...) (lines 32-38).
Then, the core of the script (lines 15-28) consists of defining the radius and center of the new sphere by using the random() IJ built-in function and applying these parameters thanks to the functions setRadius(...) and translate(...) to a temporary sphere before pasting it in the target volume.
More precisely, the setRadius(...) rescales the sphere template (Image > Scale...) and creates a new temporary sphere. Then, the function translate(...) copies each slice into the large target volume using setSlice(...) for the Z-translation and makeRectangle(...) for the X- and Y-translations.

+++ IJ snippet +++

	// Set of random spheres
	// Jean-Christophe Taveau
	// http://crazybiocomputing.blogspot.com
	maxRad=50;
	out="models";
	setPasteMode("Add");
	print("\\Clear");
	setBatchMode(true);
	// 1- Template
	newImage("sphere", "8-bit Black", maxRad*2+1, maxRad*2+1, maxRad*2+1);
	initSphere(maxRad);
	// 2- Spheres set
	newImage(out, "8-bit Black", 256, 256, 256);
	for (i=0;i<10;i++)
	{
	x=10+random()*200;
	y=10+random()*200;
	z=10+random()*200;
	setRadius("sphere","tmp",20+random()*20);
	translate("tmp",x,y,z);
	selectWindow("tmp");close();
	}
	selectWindow("models");
	setBatchMode(false);
	exit();
	// F U N C T I O N S
	function initSphere (rad)
	{
	cx=rad; cy=rad; cz=rad;
	rad2=rad*rad;
	options="code=[if (pow((x-"+cx+"),2)+pow((y-"+cy+"),2)+pow((z-"+cz+"),2)<"+rad2+")v=255] stack";
	run("Macro...", options);
	}
	function translate(sph,tx,ty,tz)
	{
	selectWindow(sph);side=getWidth();
	selectWindow(out);max=getWidth();
	for (z=1;z< side;z++)
	{
	selectWindow(sph);setSlice(z);
	run("Copy");
	selectWindow("models");
	if (tz+z<max)
	{
	setSlice(tz+z);
	makeRectangle(tx,ty,side,side);
	run("Paste");
	}
	}
	}
	function setRadius(sph_in,sph_out,rad)
	{
	newSize=rad*2+1;
	selectWindow(sph_in);
	run("Scale...", "x=- y=- z=- width="+newSize+" height="+newSize+" depth="+newSize+" interpolation=Bilinear average process create title="+sph_out);
	}

view raw gistfile1.js hosted with ❤ by GitHub

+++ End of IJ snippet +++

Conclusion

The above script is really useful to draw 3D curves and this is the subject of this post [Link].

When working in 3D, a "must" to have is the plugin TransformJ because it implemented all the 3D geometrical transformations (rotation, translation, scale,etc.).